1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; THE FOOL-BOOT-LOADER
;
; So we have just been loaded by the BIOS and are in 16-bits real mode!
; Now the following work will bee accomplished (chronologically):
;
; * BOOT_DRIVE set
;
; * 50 sectors of our kernel loaded at KERNEL_OFFSET from floppy
;
; * memory map made available at MEMMAP_OFFSET
; (check at MEMMEP_SIZE_OFFSET for number of entries)
;
; * the VESA mode specified by VESA_MODE_SELECT will be set up
; (check at VESA_MODES, and VESA_MODE_INFO
; for additional information)
;
; * interrupts disabled
;
; * 32-bit protected mode set up.
;
; * esp set to 0x90000 (Todo: take care of it!?)
;
; * A20 gate opened (Todo: really necessary?)
;
; * PICs configured
;
; * and finally we will jump into the C world to kernel_main() !
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;we want 16-bit instructions, before we switch to 32-bit protected mode.
[bits 16]
;define origin of boot record in memory: 0x7c00
;this is where the BIOS per definition will put the first
;512 bytes of data from the boot device
;The Boot record is identified by the last 2 magic bytes: 0xaa55 (?)
[org 0x7c00]
;define some constants
;where we will load our kernel into memory and some
;other memory locations
KERNEL_OFFSET equ 0x1000
MEMMAP_SIZE_OFFSET equ 0x7c00+0x600
MEMMAP_OFFSET equ 0x7c00+0x400
VESA_MODES equ 0x8300
VESA_MODE_INFO equ 0x8400
VESA_MODE_SELECT equ 0x4114
jmp boot_16 ;start boot process
;SOME Global Data, mainly info/error strings
BOOT_DRIVE:
db 0xff
STR_VERSION:
db "v0.3.1~",0
VESA_CHECK1:
db " V1.",0
VESA_CHECK2:
db " V2",0
VESA_CHECK3:
db " V2",0
CHECK_A20:
db " A20",0
;lets put our temporary GDT (Global Descriptor Table) here
;kernel should move this away
%include "boot/GDT.asm"
;include 16-bit real mode routines (print_string, disk_load, vesa_setup,check_a20)
%include "boot/disk_load_16.asm"
%include "boot/check_a20_16.asm"
%include "boot/print_string_16.asm"
%include "boot/vesa_setup_16.asm"
;include our routines for switching to 32-bit protected mode
%include "boot/pm.asm"
;pic_setup mapping routing
%include "boot/pic.asm"
;get memory map routine
%include "boot/memmap.asm"
;;;;;;;; BOOT 16-bit real ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;lets start
[bits 16]
boot_16:
mov bx, STR_VERSION
call print_string
;setup the stack
mov bp,0x8000
mov sp,bp
;remember BOOT_DRIVE (as was set by BIOS)
mov [BOOT_DRIVE],dl
;Load the KERNEL (52 sectors starting at sector 2)
mov bx,KERNEL_OFFSET
mov dh, 52
mov dl, [BOOT_DRIVE]
call disk_load
;get memory map from bios before we enter 32 bit protected mode
mov ax,0 ; set target address in es:di (0:offset)
mov es,ax
mov di,MEMMAP_OFFSET
call BiosGetMemoryMap ; this will also put the number of entries
; of the memory map at MEMMAP_SIZE_OFFSET
a20check:
mov bx, STR_VERSION
call print_string
call check_a20
cmp ax,0
je a20check ;hang if a20 is disabled!
;VESA: also setup vesa stuff before entering 32 bit protected mode
call VesaSetup
;finally lets enter Protected mode!!!
call switch_to_pm
;;;;;;;; BOOT 32-bit protected mode;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
[bits 32]
boot_32_pm:
; we could do ALL This inside the kernel!!!!!! TODO
;enable A20
;http://www.brokenthorn.com/Resources/OSDev9.html
;Method 3.1: Enables A20 through keyboard controller
;Not all keyboard controllers support this
;todo: check if this has any effect at all !?!?
;mov al, 0xdd ; command 0xdd: enable a20
;mov al, 0xdf ; command 0xdf: disable a20
;out 0x64, al ; send command to controller
;pic setup
call pic_setup
call KERNEL_OFFSET ;jump into our Kernel!
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;so we get identified as MBR
times 510-($-$$) db 0
dw 0xaa55
|
